This tutorial will show you how to reset the notification icons cache to fix any corrupted icons and remove any old icons from the taskbar system tray for your account in Windows 11.
The system tray on the taskbar corner and taskbar corner overflow menu in Windows 11 shows the notification icons for apps.
Sometimes the notification icons cache may get corrupted causing the icons to display incorrectly or distorted, and still show icons of uninstalled apps in the Other system tray icons (new name) or Taskbar corner overflow (old name) settings. When this happens, the notification icons needs to be deleted in the registry to reset and automatically recreate them.
EXAMPLE: Notifications icons on taskbar system tray
EXAMPLE: Taskbar system tray notification icons before and after reset
Here's How:
1 Click/tap on the Download button below to download the BAT file below.
Reset_taskbar_system_tray_notification_icons.bat
Download
(Contents of BAT file for reference.)
Code:
@echo off
set regPath=HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify
set regKey1=IconStreams
set regKey2=PastIconsStream
echo.
echo The explorer process must be temporarily killed before deleting your taskbar corner overflow notification icons cache.
echo.
echo Please SAVE ALL OPEN WORK before continuing.
echo.
pause
REG DELETE "HKCU\Control Panel\NotifyIconSettings" /F
echo.
taskkill /IM explorer.exe /F
echo.
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey1% ^| find /i "%regkey1%"') do goto IconStreams
echo Registry key "IconStreams" already deleted.
echo.
:verify-PastIconsStream
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey2% ^| find /i "%regkey2%"') do goto PastIconsStream
echo Registry key "PastIconsStream" already deleted.
echo.
goto restart
:IconStreams
reg delete "%regpath%" /f /v "%regkey1%"
goto verify-PastIconsStream
:PastIconsStream
reg delete "%regpath%" /f /v "%regkey2%"
:restart
echo.
echo.
echo You will need to restart the PC to finish resetting your taskbar corner overflow notification icons.
echo.
CHOICE /C:YN /M "Do you want to restart the PC now?"
IF ERRORLEVEL 2 goto no
IF ERRORLEVEL 1 goto yes
:no
echo.
echo.
echo Restarting explorer....
echo.
echo Please remember to restart the PC later to finish resetting your taskbar corner overflow notification icons.
echo.
start explorer.exe
pause
exit /B
:yes
shutdown /r /f /t 002 Save the .bat file to your desktop.
3 Unblock the .bat file.
4 Run the .bat file
5 Follow the instructions in the command prompt to reset your taskbar corner notification icons. If you do not restart the computer now, you will need to later to finish resetting your notification icons. (see screenshot below)
6 When finished, you can delete the downloaded .bat file if you like.
That's it,
Shawn Brink
Last edited:
