Solved Check if there are files in a folder in a BAT file

zelarra821 · Feb 8, 2025

Hello.

I want to check if a folder is empty or not.

- If true: message asking if I want to perform step 2.

- If false: message indicating that the folder is empty and closing the CMD window.

* IMPORTANT: when checking if a folder is empty or not, you must subtract two from the number of files, as there are two that always have to be there.

Thank you very much.

glasskuter · Feb 8, 2025

Don't know if it will help for your exact requirement or not but check this out.

Add "Find Empty Folders" context menu in Windows 11 and Windows 10

This tutorial will show you how to add a Find Empty Folders context menu for all users in Windows 10 and Windows 11. You can right click on folder, folder background, drive, or drive background and click/tap on Find Empty Folders to list the full path of all empty folders found within the...

www.elevenforum.com

zelarra821 · Feb 8, 2025

Hi.

The article is very cool, thank you very much, but it doesn't work for me.

I need to get a boolean value to use in an If and perform other tasks that I already have prepared.

antspants · Feb 8, 2025

zelarra821 said:
I need to get a boolean value to use in an If and perform other tasks that I already have prepared.

What tasks, how do you have them prepared?

garlin · Feb 8, 2025

dir /b /a:-d

/b -> brief (no output except for directory or file names)
/a:-d -> ignore all directories

Code:

@echo off
setlocal enabledelayedexpansion

set "FOLDER=%1"

echo Running dir.
echo.
dir !FOLDER!

for /f %%n in ('dir /b /a:-d !FOLDER! 2^>^&1 ^| find /c "File Not Found"') do (
    set COUNT=%%n
    if !COUNT! equ 1 (
        echo.
        echo No files found.
        exit /b
    )
)

echo.
echo Continue with my script.

endlocal

Code:

C:\Users\GARLIN\Downloads>TEST.bat FOLDER_WITH_FILES
Running dir.

 Volume in drive C has no label.
 Volume Serial Number is 5685-48D7

 Directory of C:\Users\GARLIN\Downloads\FOLDER_WITH_FILES

02/07/2025  11:28 PM    <DIR>          .
02/07/2025  11:28 PM    <DIR>          ..
09/18/2024  10:01 PM           400,738 ViVeTool-v0.3.3.zip
               1 File(s)        400,738 bytes
               2 Dir(s)  3,342,836,490,240 bytes free

Continue with my script.

C:\Users\GARLIN\Downloads>TEST.bat EMPTY_FOLDER
Running dir.

 Volume in drive C has no label.
 Volume Serial Number is 5685-48D7

 Directory of C:\Users\GARLIN\Downloads\EMPTY_FOLDER

02/07/2025  11:28 PM    <DIR>          .
02/07/2025  11:28 PM    <DIR>          ..
               0 File(s)              0 bytes
               2 Dir(s)  3,342,836,490,240 bytes free

No files found.

FreeBooter · Feb 8, 2025

Batch:

@echo off
setlocal

REM Set the folder path
set "folderPath=C:\path\to\your\folder"

REM Check if the folder is empty
if exist "%folderPath%\*" (
    echo The folder is not empty.
) else (
    echo The folder is empty.
)

endlocal

Replace C:\path\to\your\folder with the path to the folder you want to check. This script checks if there are any files or subfolders in the specified folder and prints a message accordingly. Enjoy!

antspants · Feb 8, 2025

Maybe read post 3.

FreeBooter · Feb 8, 2025

Far as i know there is no boolean value in batch scripting you have to declare it yourself for example using "Set True=1" or "Set False=0" commands.

garlin · Feb 8, 2025

FreeBooter said:
if exist "%folderPath%\*" (
echo The folder is not empty.
) else (
echo The folder is empty.
)

You can't use exist "\path\*" because "." and ".." are always defined for every folder.

Code:

C:\Users\GARLIN\Downloads>dir FOLDER_WITH_FILES
 Volume in drive C has no label.
 Volume Serial Number is 5685-48D7

 Directory of C:\Users\GARLIN\Downloads\FOLDER_WITH_FILES

02/07/2025  11:28 PM    <DIR>          .
02/07/2025  11:28 PM    <DIR>          ..
09/18/2024  10:01 PM           400,738 ViVeTool-v0.3.3.zip
               1 File(s)        400,738 bytes
               2 Dir(s)  3,342,824,955,904 bytes free

C:\Users\GARLIN\Downloads>if exist FOLDER_WITH_FILES\* (echo Not Empty) else (echo Empty)
Not Empty

Code:

C:\Users\GARLIN\Downloads>dir EMPTY_FOLDER
 Volume in drive C has no label.
 Volume Serial Number is 5685-48D7

 Directory of C:\Users\GARLIN\Downloads\EMPTY_FOLDER

02/07/2025  11:28 PM    <DIR>          .
02/07/2025  11:28 PM    <DIR>          ..
               0 File(s)              0 bytes
               2 Dir(s)  3,342,825,029,632 bytes free

C:\Users\GARLIN\Downloads>if exist EMPTY_FOLDER\* (echo Not Empty) else (echo Empty)
Not Empty

zelarra821 · Feb 8, 2025

I share bat file I want to get.

I only need not to show this two files:

So, it would finish if I excluded this two files because there's no more files.

Thanks to all.

dacrone · Feb 8, 2025

Just exclude them, or exclude all .sh

SET "ext[exclude]=.sh"

zelarra821 · Feb 8, 2025

Where do I put that code?

dacrone · Feb 8, 2025

zelarra821 said:
Where do I put that code?

Post your .bat code here. Can’t open the zip right now

zelarra821 · Feb 8, 2025

Code:

@echo off

setlocal enabledelayedexpansion

set "FOLDER="%D:\Bandeja de entrada\000 M¢vil\""

SET "ext[exclude]=.sh"

echo Running dir.
echo.
dir !FOLDER!

for /f %%n in ('dir /b /a:-d !FOLDER! 2^>^&1 ^| find /c "File Not Found"') do (
    set COUNT=%%n
    if !COUNT! equ 1 (
        echo.
        echo No files found.
        exit /b
    )
)

echo.

SET choice=

SET /p choice=Move files? [Y/N]:

IF NOT '%choice%'=='' SET choice=%choice:~0,1%

IF '%choice%'=='Y' GOTO Yes
IF '%choice%'=='y' GOTO Yes

IF '%choice%'=='N' GOTO No
IF '%choice%'=='n' GOTO No
IF '%choice%'=='' GOTO No

ECHO "%choice%" is not valid

ECHO.

GOTO start

:Yes

move /y "D:\Bandeja de entrada\000 M¢vil\Audios\*.*" "D:\Bandeja de entrada\Audios"

move /y "D:\Bandeja de entrada\000 M¢vil\Documentos\*.*" "D:\Bandeja de entrada\Documentos"

move /y "D:\Bandeja de entrada\000 M¢vil\Im genes\*.*" "D:\Bandeja de entrada\Im genes"

move /y "D:\Bandeja de entrada\000 M¢vil\V¡deos\*.*" "D:\Bandeja de entrada\V¡deos"

move /y "D:\Bandeja de entrada\000 M¢vil\ZZZ Comprobar\*.*" "D:\Bandeja de entrada\ZZZ Comprobar"

:No

EXIT

@pause

endlocal

Dronix · Feb 8, 2025

zelarra821 said:
set "FOLDER="%D:\Bandeja de entrada\000 M¢vil\""

Почему здесь %?

zelarra821 · Feb 8, 2025

It's a accent, so I have to write in that way

Dronix · Feb 8, 2025

zelarra821 said:
It's a accent, so I have to write in that way

And so set "FOLDER=D:\Bandeja de entrada\000 Móvil\" does not work?

zelarra821 · Feb 8, 2025

Not for me.

I need to know where I should put SET "ext[exclude]=.sh" in that code, please

zelarra821 · Feb 8, 2025

Could someone help me?

garlin · Feb 8, 2025

I'm not familiar with "ext[exclude]" for DIR.

dir /b /a:-d !FOLDER! 2>NUL | findstr /v /i "\!IGNORE_EXT!$" | find /c /v ""

dir /b /a:-d !FOLDER! 2>NUL
Redirect STDERR to NUL, so we don't see any "File Not Found" messages.

findstr /v /i "\!IGNORE_EXT!$"
Filter out a trailing file extension.

find /c /v ""
Count all non-empty lines.

Code:

@echo off
setlocal enabledelayedexpansion

set "FOLDER=%1"
set "IGNORE_EXT=.sh"

echo Running dir.
echo.
dir !FOLDER!

for /f %%n in ('dir /b /a:-d !FOLDER! 2^>NUL ^| findstr /v /i "\!IGNORE_EXT!$" ^| find /c /v ""') do (
    set COUNT=%%n
    if !COUNT! equ 0 (
        echo.
        echo No files found.
        exit /b
    )
)

echo.
echo Continue with my script.

endlocal

Code:

C:\Users\GARLIN\Downloads>TEST.bat DIEGO
Running dir.

 Volume in drive C has no label.
 Volume Serial Number is 5685-48D7

 Directory of C:\Users\GARLIN\Downloads\DIEGO

02/08/2025  09:45 AM    <DIR>          .
02/08/2025  09:45 AM    <DIR>          ..
02/08/2025  09:17 AM    <DIR>          Audios
02/08/2025  09:18 AM                 2 Delete.sh
02/08/2025  09:17 AM    <DIR>          Documentos
02/08/2025  09:17 AM    <DIR>          Imagenes
02/08/2025  09:18 AM                 2 Move.sh
02/08/2025  09:45 AM                 4 NORMAL.TXT
02/08/2025  09:18 AM    <DIR>          Vidoes
02/08/2025  09:18 AM    <DIR>          ZZZ Comprobar
               3 File(s)              8 bytes
               7 Dir(s)  3,339,671,646,208 bytes free

Continue with my script.

C:\Users\GARLIN\Downloads>del DIEGO\NORMAL.TXT

C:\Users\GARLIN\Downloads>TEST.bat DIEGO
Running dir.

 Volume in drive C has no label.
 Volume Serial Number is 5685-48D7

 Directory of C:\Users\GARLIN\Downloads\DIEGO

02/08/2025  09:46 AM    <DIR>          .
02/08/2025  09:46 AM    <DIR>          ..
02/08/2025  09:17 AM    <DIR>          Audios
02/08/2025  09:18 AM                 2 Delete.sh
02/08/2025  09:17 AM    <DIR>          Documentos
02/08/2025  09:17 AM    <DIR>          Imagenes
02/08/2025  09:18 AM                 2 Move.sh
02/08/2025  09:18 AM    <DIR>          Vidoes
02/08/2025  09:18 AM    <DIR>          ZZZ Comprobar
               2 File(s)              4 bytes
               7 Dir(s)  3,339,671,646,208 bytes free

No files found.

Solved Check if there are files in a folder in a BAT file

Active member

My Computer

aka Mama Glass

My Computers

Active member

My Computer

Like a rolling drone.

My Computers

Well-known member

My Computer

Well-known member

My Computer

Like a rolling drone.

My Computers

Well-known member

My Computer

Well-known member

My Computer

Active member

Attachments

My Computer

Well-known member

My Computer

Active member

My Computer

Well-known member

My Computer

Active member

My Computer

Well-known member

My Computer

Active member

My Computer

Well-known member

My Computer

Active member

My Computer

Active member

My Computer

Well-known member

My Computer

Similar threads