Increase size of BCD for failing Windows 11 upgrade from Windows 10

REM Last Updated on July 29, 2024

REM
REM * This batch file serves two purposes:
REM *
REM * 1) Windows 11 system requirements will be bypassed.
REM *
REM * 2) The drive that is specified by the user will be prepared for Windows installation.
REM

@echo off
setlocal enabledelayedexpansion
setlocal enableextensions
cd /d %~dp0

REM Set the console size to 120 columns by 25 rows.

mode con: cols=120 lines=25

cls
echo Enter the drive number to be prepared for Windows installation. Enter ONLY the drive number. If you are not sure what
echo the drive number is, please press CTRL + C and terminate this batch file, then rerun it when the drive number has
echo been determined. Please be aware that ALL data on all partitions of the drive you specify will be lost as well as
echo the original partitions on that drive.
echo.
set /p DriveNum="Enter Drive Number to be Prepared for Windows Installation: "
echo.
pause


REM ****************************************
REM * Bypass Windows 11 requirement checks *
REM ****************************************

reg add HKLM\System\Setup\LabConfig /v BypassTPMCheck /t reg_dword /d 0x00000001 /f > NUL
reg add HKLM\System\Setup\LabConfig /v BypassSecureBootCheck /t reg_dword /d 0x00000001 /f > NUL
reg add HKLM\System\Setup\LabConfig /v BypassRAMCheck /t reg_dword /d 0x00000001 /f > NUL


REM ***********************************
REM * Partition the drive for Windows *
REM ***********************************

REM Minimum EFI partition size is 100MB. I use 260MB because that is the minimum size for an advanced format disk FAT32 partition. By using 260MB
REM we guarantee this to work on all systems.
REM
REM I use a larger than normal recovery partition of 2GB to make sure I will not encounter problems in the future.

( echo select disk %DriveNum%
echo clean
echo convert gpt
echo create partition efi size=260
echo format fs=fat32 quick label="System"
echo create partition msr size=128
echo create partition primary
echo shrink desired=2048
echo format fs=ntfs quick label="Windows"
echo create partition primary
echo set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"
echo gpt attributes=0x8000000000000001
echo format fs=ntfs quick label="Recovery Tools"
) | diskpart

cls
echo Preparation of drive %DriveNum% has been completed. Please continue with installation.
echo.
echo Please note that if you are currently on the screen showing the available disks during installation, you should select the option to
echo refresh this information so that it can reflect the changes that were just made. If you are not yet up to that screen during
echo installation then please ignore this message.
echo.
pause